mirror of
https://github.com/hanzoai/datastore.git
synced 2026-10-30 14:48:37 +00:00
zeekay
3094cd1739
Configure now COMPLETES ("Configuring done (19.3s)") and the build died in the
generate step instead, on "No SOURCES given to target" for _zxc, _zxc_*_avx2/512,
_simdutf and libdeflate.
The targets are not empty; the paths were. CMake defines <PROJECT>_SOURCE_DIR,
and CMakeLists.txt:18 declares project(Datastore), so ClickHouse_SOURCE_DIR is
simply an undefined variable that expands to the empty string. Every contrib
wrapper still spelling it that way built its source path as "/contrib/zxc" or
"/contrib/simdutf/src" — rooted at /, not at the source tree — so the globs
matched nothing and add_library was handed an empty list. An undefined variable
is not an error in CMake, which is why this surfaced as a missing-sources
complaint about the target rather than a bad path.
This is the same unfinished rename as the previous commit wearing different
clothes. Swept both spellings across every in-repo cmake file: exactly two tokens,
ClickHouse_SOURCE_DIR and ClickHouse_BINARY_DIR, 23 occurrences in 13 files, all
of them contrib/*-cmake wrappers plus src/CMakeLists.txt. The submodules
themselves are untouched — the wrappers are ours, contrib/<name>-cmake is not a
.gitmodules path.
Renamed rather than aliased. A one-line set(ClickHouse_SOURCE_DIR
${Datastore_SOURCE_DIR}) in the root would also have worked and would cost less
on the next upstream merge, but the tree already carries hundreds of
Datastore_SOURCE_DIR uses in these same directories: the choice to rename was
made when the project was renamed, and these 13 files are the remainder of that
job, not a new decision. Two spellings for one path is the thing that produced
this bug in the first place.
58 lines
2.6 KiB
CMake
58 lines
2.6 KiB
CMake
set(LIBCXXABI_SOURCE_DIR "${Datastore_SOURCE_DIR}/contrib/llvm-project/libcxxabi")
|
|
|
|
set(SRCS
|
|
"${LIBCXXABI_SOURCE_DIR}/src/abort_message.cpp"
|
|
"${LIBCXXABI_SOURCE_DIR}/src/cxa_aux_runtime.cpp"
|
|
"${LIBCXXABI_SOURCE_DIR}/src/cxa_default_handlers.cpp"
|
|
"${LIBCXXABI_SOURCE_DIR}/src/cxa_demangle.cpp"
|
|
"${LIBCXXABI_SOURCE_DIR}/src/cxa_exception.cpp"
|
|
"${LIBCXXABI_SOURCE_DIR}/src/cxa_exception_storage.cpp"
|
|
"${LIBCXXABI_SOURCE_DIR}/src/cxa_guard.cpp"
|
|
"${LIBCXXABI_SOURCE_DIR}/src/cxa_handlers.cpp"
|
|
"${LIBCXXABI_SOURCE_DIR}/src/cxa_personality.cpp"
|
|
"${LIBCXXABI_SOURCE_DIR}/src/cxa_thread_atexit.cpp"
|
|
"${LIBCXXABI_SOURCE_DIR}/src/cxa_vector.cpp"
|
|
"${LIBCXXABI_SOURCE_DIR}/src/cxa_virtual.cpp"
|
|
"${LIBCXXABI_SOURCE_DIR}/src/fallback_malloc.cpp"
|
|
"${LIBCXXABI_SOURCE_DIR}/src/private_typeinfo.cpp"
|
|
"${LIBCXXABI_SOURCE_DIR}/src/stdlib_exception.cpp"
|
|
"${LIBCXXABI_SOURCE_DIR}/src/stdlib_new_delete.cpp"
|
|
"${LIBCXXABI_SOURCE_DIR}/src/stdlib_stdexcept.cpp"
|
|
"${LIBCXXABI_SOURCE_DIR}/src/stdlib_typeinfo.cpp"
|
|
)
|
|
|
|
add_library(cxxabi ${SRCS})
|
|
set_target_properties(cxxabi PROPERTIES FOLDER "contrib/libcxxabi-cmake")
|
|
|
|
# Third party library may have substandard code.
|
|
target_compile_options(cxxabi PRIVATE -w)
|
|
|
|
target_include_directories(cxxabi SYSTEM BEFORE
|
|
PUBLIC $<BUILD_INTERFACE:${LIBCXXABI_SOURCE_DIR}/include>
|
|
PRIVATE $<BUILD_INTERFACE:${LIBCXXABI_SOURCE_DIR}/../libcxx/include>
|
|
PRIVATE $<BUILD_INTERFACE:${LIBCXXABI_SOURCE_DIR}/../libcxx/src>
|
|
)
|
|
target_compile_definitions(cxxabi PRIVATE -D_LIBCPP_BUILDING_LIBRARY -DHAS_THREAD_LOCAL)
|
|
# If we don't disable UBSan, infinite recursion happens in dynamic_cast.
|
|
target_compile_options(cxxabi PRIVATE -nostdinc++ -fno-sanitize=undefined -Wno-macro-redefined)
|
|
# Demangling is very slow under MSan due to frame-pointers, it is OK to omit them for cxxabi anyway
|
|
target_compile_options(cxxabi PRIVATE -fomit-frame-pointer -momit-leaf-frame-pointer)
|
|
# We sacrifice origins tracking here to make demangling faster (unlikely that the origin will be here anyway)
|
|
if (SANITIZE STREQUAL "memory")
|
|
target_compile_options(cxxabi PRIVATE -fno-sanitize-memory-track-origins)
|
|
endif()
|
|
target_link_libraries(cxxabi PUBLIC unwind)
|
|
|
|
# Enable capturing stack traces for all exceptions.
|
|
target_compile_definitions(cxxabi PUBLIC -DSTD_EXCEPTION_HAS_STACK_TRACE=1)
|
|
|
|
if (USE_MUSL)
|
|
target_compile_definitions(cxxabi PUBLIC -D_LIBCPP_HAS_MUSL_LIBC)
|
|
add_dependencies(cxxabi musl-headers)
|
|
# The arch dirs are not in the toolchain flags to avoid include order issues in musl's own build.
|
|
target_include_directories(cxxabi SYSTEM BEFORE PRIVATE
|
|
"${Datastore_SOURCE_DIR}/contrib/musl/arch/${MUSL_ARCH}"
|
|
"${Datastore_SOURCE_DIR}/contrib/musl/arch/generic"
|
|
)
|
|
endif()
|