datastore/contrib/CMakeLists.txt

#"${folder}/CMakeLists.txt" Third-party libraries may have substandard code.

set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -w -ffunction-sections -fdata-sections")
set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -w -ffunction-sections -fdata-sections")
if (OS_LINUX)
    set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -faddrsig")
    set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -faddrsig")
endif ()

if (SANITIZE STREQUAL "undefined" OR SANITIZE STREQUAL "address,undefined")
    # 3rd-party libraries usually not intended to work with UBSan.
    add_compile_options(-fno-sanitize=undefined)
endif()

set_property(DIRECTORY PROPERTY EXCLUDE_FROM_ALL 1)
set(WITH_COVERAGE OFF)
# add_contrib cmake_folder[ base_folder1[, ...base_folderN]]
function(add_contrib cmake_folder)
    if (ARGN)
        set(base_folders ${ARGN})
    else()
        set(base_folders ${cmake_folder})
    endif()

    foreach (base_folder ${base_folders})
        # some typos in the code
        if (NOT IS_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/${base_folder}")
            message(FATAL_ERROR "No such base folder '${base_folder}' (for '${cmake_folder}' cmake folder). Typo in the base folder name?")
        endif()

        file(GLOB contrib_files "${base_folder}/*")
        if (NOT contrib_files)
            # Checking out *all* submodules takes > 5 min. Therefore, the smoke build ("FastTest") in CI initializes only the set of
            # submodules minimally needed for a build and we cannot assume here that all submodules are populated.
            message(STATUS "submodule ${base_folder} is missing or empty. to fix try run:")
            message(STATUS "    git submodule update --init")
            return()
        endif()
    endforeach()

    message(STATUS "Adding contrib module ${base_folders} (configuring with ${cmake_folder})")
    add_subdirectory (${cmake_folder})
endfunction()

# Use the original launchers for the projects that are needed for source code generation:
# protoc and llvm-tlbgen.
disable_heavy_build_check_if_needed()
disable_dummy_launchers_if_needed()

# We need to add OpenSSL first so that all our projects use our own version instead of the system one.
add_contrib (openssl-cmake openssl)  # Needed for delta-lake

if (USE_MUSL)
    add_contrib (musl-cmake musl)
endif()
add_contrib (abseil-cpp-cmake abseil-cpp)
add_contrib (zlib-ng-cmake zlib-ng)
add_contrib (google-protobuf-cmake google-protobuf)
add_contrib (compiler-rt-cmake llvm-project)
add_contrib (libllvmlibc-cmake llvm-project)
add_contrib (llvm-project-cmake llvm-project)

enable_dummy_launchers_if_needed()
enable_heavy_build_check_if_needed()

add_contrib (miniselect-cmake miniselect)
# mapbox-geometry must precede wagyu: the wagyu interface target links ch_contrib::mapbox_geometry.
add_contrib (mapbox-geometry-cmake mapbox-geometry)
add_contrib (wagyu-cmake wagyu)
add_contrib (pdqsort-cmake pdqsort)
add_contrib (ipnsort-cmake ipnsort)
add_contrib (driftsort-cmake driftsort)
add_contrib (pocketfft-cmake pocketfft)
add_contrib (crc32-vpmsum-cmake crc32-vpmsum)
add_contrib (sparsehash-c11-cmake sparsehash-c11)
add_contrib (magic-enum-cmake magic_enum)
add_contrib (boost-cmake boost)
add_contrib (cctz-cmake cctz)
add_contrib (consistent-hashing)
add_contrib (zmij-cmake zmij)
add_contrib (vectorscan-cmake vectorscan)
add_contrib (jemalloc-cmake jemalloc)
add_contrib (libcpuid-cmake libcpuid)
add_contrib (libdivide-cmake)
add_contrib (libmetrohash)
add_contrib (lz4-cmake lz4)
add_contrib (libdeflate-cmake libdeflate)
add_contrib (murmurhash)
add_contrib (replxx-cmake replxx)
add_contrib (zap-cmake zap)
# capnproto dropped: contrib/zap IS the debranded Cap'n Proto and provides the kj toolkit; building
# capnproto-cmake too would duplicate kj. The CapnProto data FORMAT stays gated off (USE_CAPNP=0,
# no ch_contrib::capnp alias) — same as before the 26.6 merge.
# libpng dropped upstream in 26.7: PNG is written directly, no contrib/libpng.
add_contrib (yaml-cpp-cmake yaml-cpp)
add_contrib (re2-cmake re2)
add_contrib (xz-cmake xz)
add_contrib (brotli-cmake brotli)
add_contrib (double-conversion-cmake double-conversion)
add_contrib (croaring-cmake croaring)
add_contrib (zstd-cmake zstd)
add_contrib (zxc-cmake zxc)
add_contrib (bzip2-cmake bzip2)
add_contrib (minizip-ng-cmake minizip-ng)
add_contrib (snappy-cmake snappy)
add_contrib (thrift-cmake thrift)
add_contrib (StringZilla-cmake StringZilla)
# parquet/arrow/orc
add_contrib (xsimd-cmake xsimd) # required by arrow's SIMD codepaths
add_contrib (arrow-cmake arrow) # requires: snappy, thrift, double-conversion, xsimd
add_contrib (avro-cmake avro) # requires: snappy
add_contrib (openldap-cmake openldap)
add_contrib (msgpack-c-cmake msgpack-c)
add_contrib (libarchive-cmake libarchive)

add_contrib (corrosion-cmake corrosion)
add_contrib (delta-kernel-rs-cmake delta-kernel-rs)
# chdig (the Datastore "dig" TUI debugger) and its datastore-rs Rust client dependency are a
# third-party Datastore tool — removed from datastore (USE_CHDIG=0; the `datastore dig` entry
# point compiles out). This also strips the bulk of vendored datastore-* strings from the binary.
add_contrib (wasmedge-cmake wasmedge)

if (ENABLE_FUZZING)
    add_contrib (libprotobuf-mutator-cmake libprotobuf-mutator)
endif()

add_contrib (wyhash-cmake wyhash)
add_contrib (cityhash102)
add_contrib (libfarmhash)
add_contrib (icu-cmake icu)
add_contrib (h3-cmake h3)
add_contrib (mariadb-connector-c-cmake mariadb-connector-c)
add_contrib (libfiu-cmake libfiu)

if (ENABLE_TESTS)
    add_contrib (googletest-cmake googletest)
endif()

add_contrib (libfuzzer-cmake llvm-project)
add_contrib (libxml2-cmake libxml2)

add_contrib (aws-cmake
    aws
    aws-c-auth
    aws-c-cal
    aws-c-common
    aws-c-compression
    aws-c-event-stream
    aws-c-http
    aws-c-io
    aws-c-mqtt
    aws-c-s3
    aws-c-sdkutils
    aws-checksums
    aws-crt-cpp
    aws-cmake
)

add_contrib (simdjson-cmake simdjson)
add_contrib (simdutf-cmake simdutf)
add_contrib (rapidjson-cmake rapidjson)
add_contrib (fastops-cmake fastops)
add_contrib (libuv-cmake libuv)
add_contrib (liburing-cmake liburing)
add_contrib (amqpcpp-cmake AMQP-CPP) # requires: libuv
add_contrib (cassandra-cmake cassandra) # requires: libuv
add_contrib (azure-cmake azure)
add_contrib (fmtlib-cmake fmtlib)
add_contrib (krb5-cmake krb5)
add_contrib (cyrus-sasl-cmake cyrus-sasl) # for krb5
add_contrib (libgsasl-cmake libgsasl) # requires krb5
add_contrib (librdkafka-cmake librdkafka) # requires: libgsasl
add_contrib (nats-io-cmake nats-io)
add_contrib (isa-l-cmake isa-l)
add_contrib (libhdfs3-cmake libhdfs3) # requires: google-protobuf, krb5, isa-l
add_contrib (hive-metastore-cmake hive-metastore) # requires: thrift, avro, arrow, libhdfs3
add_contrib (cppkafka-cmake cppkafka)

option(ENABLE_LIBPQXX "Enable PostgreSQL" ${ENABLE_LIBRARIES})
if (ENABLE_LIBPQXX)
    add_contrib (postgres-cmake postgres)
    add_contrib (libpqxx-cmake libpqxx)
endif()

add_contrib (rocksdb-cmake rocksdb) # requires: jemalloc, snappy, zlib, lz4, zstd, liburing
add_contrib (nuraft-cmake NuRaft)
add_contrib (fast_float-cmake fast_float)
add_contrib (idna-cmake idna)
add_contrib (datasketches-cpp-cmake datasketches-cpp)
add_contrib (sqids-cpp-cmake sqids-cpp)

option(USE_MONGODB "Enable MongoDB support" ${ENABLE_LIBRARIES})
if (USE_MONGODB)
    add_contrib (mongo-c-driver-cmake mongo-c-driver) # requires: zlib
    add_contrib (mongo-cxx-driver-cmake mongo-cxx-driver) # requires: libmongoc, libbson
endif()

add_contrib (libstemmer-c-cmake libstemmer_c)

option(ENABLE_NLP "Enable NLP functions support" ${ENABLE_LIBRARIES})
if (ENABLE_NLP)
    add_contrib (wordnet-blast-cmake wordnet-blast)
    add_contrib (lemmagen-c-cmake lemmagen-c)
    add_contrib (cld2-cmake cld2)
endif()

add_contrib (sqlite-cmake sqlite-amalgamation)
add_contrib (s2geometry-cmake s2geometry)
add_contrib (c-ares-cmake c-ares)

add_contrib (morton-nd-cmake morton-nd)
if (ARCH_S390X)
    add_contrib(crc32-s390x-cmake crc32-s390x)
endif()

option(ENABLE_SIMSIMD "Enable SimSIMD" ${ENABLE_LIBRARIES})
if (ENABLE_SIMSIMD)
    add_contrib (SimSIMD-cmake SimSIMD)
else ()
    message(STATUS "Not using SimSIMD")
endif ()

option(ENABLE_USEARCH "Enable USearch" ${ENABLE_LIBRARIES})
if (ENABLE_USEARCH)
    add_contrib (FP16-cmake FP16)
    if (NOT ENABLE_SIMSIMD)
        add_contrib (SimSIMD-cmake SimSIMD)
    endif()
    add_contrib (usearch-cmake usearch) # requires: FP16, SimdSIMD
else ()
    message(STATUS "Not using USearch")
endif ()

add_contrib (xxHash-cmake xxHash)

add_contrib (libbcrypt-cmake libbcrypt)

add_contrib (google-benchmark-cmake google-benchmark)
add_contrib (ulid-c-cmake ulid-c)

add_contrib (libssh-cmake libssh)

add_contrib (prometheus-protobufs-cmake prometheus-protobufs prometheus-protobufs-gogo)
add_contrib (antlr4-cpp-runtime-cmake antlr4-cpp-runtime)
add_contrib (antlr4-grammars-cmake antlr4-grammars)

add_contrib(simdcomp-cmake simdcomp)

add_contrib (numactl-cmake numactl)

# `crc32c` is a small portable library used by the snappy framing format in
# `SnappyWriteBuffer`/`SnappyFramedReadBuffer`, so it is always built when libraries are enabled.
add_contrib (crc32c-cmake crc32c)

# Google Cloud Cpp — DROPPED from datastore. It is gRPC-based (gRPC is removed) and redundant:
# GCS is reached through its S3-compatible endpoint via the AWS S3 client, and secrets/KMS go
# through Hanzo KMS — not GCP KMS. Object storage = S3 only. Do not re-add without re-adding gRPC.
message(STATUS "Not using Google Cloud Cpp (dropped: gRPC-based; use S3 + Hanzo KMS)")

add_contrib (jwt-cpp-cmake jwt-cpp)

add_contrib (sha3iuf-cmake SHA3IUF)

add_contrib (ai-sdk-cpp-cmake ai-sdk-cpp)

add_contrib (bech32)

add_contrib (libcotp-cmake libcotp)

add_contrib (clickstack-cmake clickstack)

add_contrib (librseq-cmake librseq)
add_contrib (silk-cmake silk)

add_contrib (sz3-cmake sz3)

# Put all targets defined here and in subdirectories under "contrib/<immediate-subdir>" folders in GUI-based IDEs.
# Some of third-party projects may override CMAKE_FOLDER or FOLDER property of their targets, so they would not appear
# in "contrib/..." as originally planned, so we workaround this by fixing FOLDER properties of all targets manually,
# instead of controlling it via CMAKE_FOLDER.

function (ensure_target_rooted_in _target _folder)
    # Skip aliases and INTERFACE library targets, since FOLDER property is not available/writable for them.
    get_target_property (_target_aliased "${_target}" ALIASED_TARGET)
    get_target_property (_target_type "${_target}" TYPE)
    if (_target_aliased OR _target_type STREQUAL "INTERFACE_LIBRARY")
        return ()
    endif ()

    # Read the original FOLDER property value, if any.
    get_target_property (_folder_prop "${_target}" FOLDER)

    # Normalize that value, so we avoid possible repetitions in folder names.

    if (NOT _folder_prop)
        set (_folder_prop "")
    endif ()

    if (CMAKE_FOLDER AND _folder_prop MATCHES "^${CMAKE_FOLDER}/(.*)\$")
        set (_folder_prop "${CMAKE_MATCH_1}")
    endif ()

    if (_folder AND _folder_prop MATCHES "^${_folder}/(.*)\$")
        set (_folder_prop "${CMAKE_MATCH_1}")
    endif ()

    if (_folder)
        set (_folder_prop "${_folder}/${_folder_prop}")
    endif ()

    if (CMAKE_FOLDER)
        set (_folder_prop "${CMAKE_FOLDER}/${_folder_prop}")
    endif ()

    # Set the updated FOLDER property value back.
    set_target_properties ("${_target}" PROPERTIES FOLDER "${_folder_prop}")
endfunction ()

function (ensure_own_targets_are_rooted_in _dir _folder)
    get_directory_property (_targets DIRECTORY "${_dir}" BUILDSYSTEM_TARGETS)
    foreach (_target IN LISTS _targets)
        ensure_target_rooted_in ("${_target}" "${_folder}")
    endforeach ()
endfunction ()

function (ensure_all_targets_are_rooted_in _dir _folder)
    ensure_own_targets_are_rooted_in ("${_dir}" "${_folder}")

    get_property (_sub_dirs DIRECTORY "${_dir}" PROPERTY SUBDIRECTORIES)
    foreach (_sub_dir IN LISTS _sub_dirs)
        ensure_all_targets_are_rooted_in ("${_sub_dir}" "${_folder}")
    endforeach ()
endfunction ()

function (organize_ide_folders_2_level _dir)
    get_filename_component (_dir_name "${_dir}" NAME)
    ensure_own_targets_are_rooted_in ("${_dir}" "${_dir_name}")

    # Note, that we respect only first two levels of nesting, we don't want to
    # reorganize target folders further within each third-party dir.

    get_property (_sub_dirs DIRECTORY "${_dir}" PROPERTY SUBDIRECTORIES)
    foreach (_sub_dir IN LISTS _sub_dirs)
        get_filename_component (_sub_dir_name "${_sub_dir}" NAME)
        ensure_all_targets_are_rooted_in ("${_sub_dir}" "${_dir_name}/${_sub_dir_name}")
    endforeach ()
endfunction ()

organize_ide_folders_2_level ("${CMAKE_CURRENT_LIST_DIR}")