mirror of
https://github.com/hanzoai/kv.git
synced 2026-11-09 16:05:35 +00:00
Carries on from where #3161 left off. The test-sanitizer-address-large-memory jobs were being OOM-killed on GitHub-hosted runners (15.6GB RAM) due to ASAN's 2-3x memory overhead. Changes: - Skip 4GB quicklist compression test under ASAN (requires ~16-24GB with dual buffers + ASAN overhead) - Reduce integration test sizes from 5GB to 4.1GB (preserves >4GB 32-bit boundary coverage) - Reduce XADD iterations from 10 to 3 - Add memory monitoring to track minimum free memory during CI runs Signed-off-by: Rain Valentine <[email protected]>
107 lines
3.8 KiB
Tcl
107 lines
3.8 KiB
Tcl
# One XADD with one huge >4GiB field (reduced from 5GB for CI memory limits)
|
|
# Must exceed 2^32 to require more than 32 bits to address
|
|
# Expected to fail resulting in an empty stream
|
|
run_solo {violations} {
|
|
start_server [list overrides [list save ""] tags {"large-memory"}] {
|
|
test {XADD one huge field} {
|
|
r config set proto-max-bulk-len 10000000000 ;#10gb
|
|
r config set client-query-buffer-limit 10000000000 ;#10gb
|
|
r write "*5\r\n\$4\r\nXADD\r\n\$2\r\nS1\r\n\$1\r\n*\r\n"
|
|
r write "\$1\r\nA\r\n"
|
|
catch {
|
|
write_big_bulk 4300000000 ;#~4GiB, >2^32
|
|
} err
|
|
assert_match {*too large*} $err
|
|
r xlen S1
|
|
} {0}
|
|
}
|
|
|
|
# One XADD with one huge (exactly nearly) 4GB field
|
|
# This uncovers the overflow in lpEncodeGetType
|
|
# Expected to fail resulting in an empty stream
|
|
start_server [list overrides [list save ""] tags {"large-memory"}] {
|
|
test {XADD one huge field - 1} {
|
|
r config set proto-max-bulk-len 10000000000 ;#10gb
|
|
r config set client-query-buffer-limit 10000000000 ;#10gb
|
|
r write "*5\r\n\$4\r\nXADD\r\n\$2\r\nS1\r\n\$1\r\n*\r\n"
|
|
r write "\$1\r\nA\r\n"
|
|
catch {
|
|
write_big_bulk 4294967295 ;#4gb-1
|
|
} err
|
|
assert_match {*too large*} $err
|
|
r xlen S1
|
|
} {0}
|
|
}
|
|
|
|
# Gradually add big stream fields using repeated XADD calls
|
|
# Reduced from 10 to 3 iterations to fit in 16GB CI runners with ASAN overhead
|
|
start_server [list overrides [list save ""] tags {"large-memory"}] {
|
|
test {several XADD big fields} {
|
|
r config set stream-node-max-bytes 0
|
|
for {set j 0} {$j<3} {incr j} {
|
|
r xadd stream * 1 $::str500 2 $::str500
|
|
}
|
|
r ping
|
|
r xlen stream
|
|
} {3}
|
|
}
|
|
|
|
# Add over 4GB to a single stream listpack (one XADD command)
|
|
# Expected to fail resulting in an empty stream
|
|
start_server [list overrides [list save ""] tags {"large-memory"}] {
|
|
test {single XADD big fields} {
|
|
r write "*23\r\n\$4\r\nXADD\r\n\$1\r\nS\r\n\$1\r\n*\r\n"
|
|
for {set j 0} {$j<10} {incr j} {
|
|
r write "\$1\r\n$j\r\n"
|
|
write_big_bulk 500000000 "" yes ;#500mb
|
|
}
|
|
r flush
|
|
catch {r read} err
|
|
assert_match {*too large*} $err
|
|
r xlen S
|
|
} {0}
|
|
}
|
|
|
|
# Gradually add big hash fields using repeated HSET calls
|
|
# This reproduces the overflow in the call to ziplistResize
|
|
# Object will be converted to hashtable encoding
|
|
start_server [list overrides [list save ""] tags {"large-memory"}] {
|
|
r config set hash-max-ziplist-value 1000000000 ;#1gb
|
|
test {hash with many big fields} {
|
|
for {set j 0} {$j<10} {incr j} {
|
|
r hset h $j $::str500
|
|
}
|
|
r object encoding h
|
|
} {hashtable}
|
|
}
|
|
|
|
# Add over 4GB to a single hash field (one HSET command)
|
|
# Object will be converted to hashtable encoding
|
|
# Reduced from 5GB; must exceed 2^32 to test >4GiB (32-bit boundary) behavior
|
|
start_server [list overrides [list save ""] tags {"large-memory"}] {
|
|
test {hash with one huge field} {
|
|
catch {r config set hash-max-ziplist-value 10000000000} ;#10gb
|
|
r config set proto-max-bulk-len 10000000000 ;#10gb
|
|
r config set client-query-buffer-limit 10000000000 ;#10gb
|
|
r write "*4\r\n\$4\r\nHSET\r\n\$2\r\nH1\r\n"
|
|
r write "\$1\r\nA\r\n"
|
|
write_big_bulk 4300000000 ;#~4GiB, >2^32
|
|
r object encoding H1
|
|
} {hashtable}
|
|
}
|
|
} ;# run_solo
|
|
|
|
# SORT which stores an integer encoded element into a list.
|
|
# Just for coverage, no news here.
|
|
start_server [list overrides [list save ""] ] {
|
|
test {SORT adds integer field to list} {
|
|
r set S1 asdf
|
|
r set S2 123 ;# integer encoded
|
|
assert_encoding "int" S2
|
|
r sadd myset 1 2
|
|
r mset D1 1 D2 2
|
|
r sort myset by D* get S* store mylist
|
|
r llen mylist
|
|
} {2} {cluster:skip}
|
|
}
|