mirror of
https://github.com/luxfi/erc-3643.git
synced 2026-10-30 16:58:28 +00:00
zeekay
7eb9e4be08
OpenZeppelin v5 dropped parameterless __Ownable_init() and Ownable() in favor of explicit owner argument. Required for solc 0.8.31 + OZ v5 build (see partner/contracts foundry.toml). 10 files: ModularCompliance, AbstractModuleUpgradeable, TREXFactory, TREXImplementationAuthority, ClaimTopicsRegistry, IdentityRegistry, IdentityRegistryStorage, TrustedIssuersRegistry, AgentRole, Token.
180 lines
8.4 KiB
Solidity
180 lines
8.4 KiB
Solidity
// SPDX-License-Identifier: GPL-3.0
|
|
//
|
|
// :+#####%%%%%%%%%%%%%%+
|
|
// .-*@@@%+.:+%@@@@@%%#***%@@%=
|
|
// :=*%@@@#=. :#@@% *@@@%=
|
|
// .-+*%@%*-.:+%@@@@@@+. -*+: .=#. :%@@@%-
|
|
// :=*@@@@%%@@@@@@@@@%@@@- .=#@@@%@%= =@@@@#.
|
|
// -=+#%@@%#*=:. :%@@@@%. -*@@#*@@@@@@@#=:- *@@@@+
|
|
// =@@%=:. :=: *@@@@@%#- =%*%@@@@#+-. =+ :%@@@%-
|
|
// -@@%. .+@@@ =+=-. @@#- +@@@%- =@@@@%:
|
|
// :@@@. .+@@#%: : .=*=-::.-%@@@+*@@= +@@@@#.
|
|
// %@@: +@%%* =%@@@@@@@@@@@#. .*@%- +@@@@*.
|
|
// #@@= .+@@@@%:=*@@@@@- :%@%: .*@@@@+
|
|
// *@@* +@@@#-@@%-:%@@* +@@#. :%@@@@-
|
|
// -@@% .:-=++*##%%%@@@@@@@@@@@@*. :@+.@@@%: .#@@+ =@@@@#:
|
|
// .@@@*-+*#%%%@@@@@@@@@@@@@@@@%%#**@@%@@@. *@=*@@# :#@%= .#@@@@#-
|
|
// -%@@@@@@@@@@@@@@@*+==-:-@@@= *@# .#@*-=*@@@@%= -%@@@* =@@@@@%-
|
|
// -+%@@@#. %@%%= -@@:+@: -@@* *@@*-:: -%@@%=. .*@@@@@#
|
|
// *@@@* +@* *@@##@@- #@*@@+ -@@= . :+@@@#: .-+@@@%+-
|
|
// +@@@%*@@:..=@@@@* .@@@* .#@#. .=+- .=%@@@*. :+#@@@@*=:
|
|
// =@@@@%@@@@@@@@@@@@@@@@@@@@@@%- :+#*. :*@@@%=. .=#@@@@%+:
|
|
// .%@@= ..... .=#@@+. .#@@@*: -*%@@@@%+.
|
|
// +@@#+===---:::... .=%@@*- +@@@+. -*@@@@@%+.
|
|
// -@@@@@@@@@@@@@@@@@@@@@@%@@@@= -@@@+ -#@@@@@#=.
|
|
// ..:::---===+++***###%%%@@@#- .#@@+ -*@@@@@#=.
|
|
// @@@@@@+. +@@*. .+@@@@@%=.
|
|
// -@@@@@= =@@%: -#@@@@%+.
|
|
// +@@@@@. =@@@= .+@@@@@*:
|
|
// #@@@@#:%@@#. :*@@@@#-
|
|
// @@@@@%@@@= :#@@@@+.
|
|
// :@@@@@@@#.:#@@@%-
|
|
// +@@@@@@-.*@@@*:
|
|
// #@@@@#.=@@@+.
|
|
// @@@@+-%@%=
|
|
// :@@@#%@%=
|
|
// +@@@@%-
|
|
// :#%%=
|
|
//
|
|
/**
|
|
* NOTICE
|
|
*
|
|
* The T-REX software is licensed under a proprietary license or the GPL v.3.
|
|
* If you choose to receive it under the GPL v.3 license, the following applies:
|
|
* T-REX is a suite of smart contracts implementing the ERC-3643 standard and
|
|
* developed by Tokeny to manage and transfer financial assets on EVM blockchains
|
|
*
|
|
* Copyright (C) 2023, Tokeny sàrl.
|
|
*
|
|
* This program is free software: you can redistribute it and/or modify
|
|
* it under the terms of the GNU General Public License as published by
|
|
* the Free Software Foundation, either version 3 of the License, or
|
|
* (at your option) any later version.
|
|
*
|
|
* This program is distributed in the hope that it will be useful,
|
|
* but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
* GNU General Public License for more details.
|
|
*
|
|
* You should have received a copy of the GNU General Public License
|
|
* along with this program. If not, see <https://www.gnu.org/licenses/>.
|
|
*/
|
|
|
|
pragma solidity ^0.8.17;
|
|
|
|
import "@onchain-id/solidity/contracts/interface/IIdentity.sol";
|
|
|
|
import "../../roles/AgentRoleUpgradeable.sol";
|
|
import "../interface/IIdentityRegistryStorage.sol";
|
|
import "../storage/IRSStorage.sol";
|
|
|
|
contract IdentityRegistryStorage is IIdentityRegistryStorage, AgentRoleUpgradeable, IRSStorage {
|
|
|
|
function init() external initializer {
|
|
__Ownable_init(msg.sender);
|
|
}
|
|
|
|
/**
|
|
* @dev See {IIdentityRegistryStorage-addIdentityToStorage}.
|
|
*/
|
|
function addIdentityToStorage(
|
|
address _userAddress,
|
|
IIdentity _identity,
|
|
uint16 _country
|
|
) external override onlyAgent {
|
|
require(
|
|
_userAddress != address(0)
|
|
&& address(_identity) != address(0)
|
|
, "invalid argument - zero address");
|
|
require(address(_identities[_userAddress].identityContract) == address(0), "address stored already");
|
|
_identities[_userAddress].identityContract = _identity;
|
|
_identities[_userAddress].investorCountry = _country;
|
|
emit IdentityStored(_userAddress, _identity);
|
|
}
|
|
|
|
/**
|
|
* @dev See {IIdentityRegistryStorage-modifyStoredIdentity}.
|
|
*/
|
|
function modifyStoredIdentity(address _userAddress, IIdentity _identity) external override onlyAgent {
|
|
require(
|
|
_userAddress != address(0)
|
|
&& address(_identity) != address(0)
|
|
, "invalid argument - zero address");
|
|
require(address(_identities[_userAddress].identityContract) != address(0), "address not stored yet");
|
|
IIdentity oldIdentity = _identities[_userAddress].identityContract;
|
|
_identities[_userAddress].identityContract = _identity;
|
|
emit IdentityModified(oldIdentity, _identity);
|
|
}
|
|
|
|
/**
|
|
* @dev See {IIdentityRegistryStorage-modifyStoredInvestorCountry}.
|
|
*/
|
|
function modifyStoredInvestorCountry(address _userAddress, uint16 _country) external override onlyAgent {
|
|
require(_userAddress != address(0), "invalid argument - zero address");
|
|
require(address(_identities[_userAddress].identityContract) != address(0), "address not stored yet");
|
|
_identities[_userAddress].investorCountry = _country;
|
|
emit CountryModified(_userAddress, _country);
|
|
}
|
|
|
|
/**
|
|
* @dev See {IIdentityRegistryStorage-removeIdentityFromStorage}.
|
|
*/
|
|
function removeIdentityFromStorage(address _userAddress) external override onlyAgent {
|
|
require(_userAddress != address(0), "invalid argument - zero address");
|
|
require(address(_identities[_userAddress].identityContract) != address(0), "address not stored yet");
|
|
IIdentity oldIdentity = _identities[_userAddress].identityContract;
|
|
delete _identities[_userAddress];
|
|
emit IdentityUnstored(_userAddress, oldIdentity);
|
|
}
|
|
|
|
/**
|
|
* @dev See {IIdentityRegistryStorage-bindIdentityRegistry}.
|
|
*/
|
|
function bindIdentityRegistry(address _identityRegistry) external override {
|
|
require(_identityRegistry != address(0), "invalid argument - zero address");
|
|
require(_identityRegistries.length < 300, "cannot bind more than 300 IR to 1 IRS");
|
|
addAgent(_identityRegistry);
|
|
_identityRegistries.push(_identityRegistry);
|
|
emit IdentityRegistryBound(_identityRegistry);
|
|
}
|
|
|
|
/**
|
|
* @dev See {IIdentityRegistryStorage-unbindIdentityRegistry}.
|
|
*/
|
|
function unbindIdentityRegistry(address _identityRegistry) external override {
|
|
require(_identityRegistry != address(0), "invalid argument - zero address");
|
|
require(_identityRegistries.length > 0, "identity registry is not stored");
|
|
uint256 length = _identityRegistries.length;
|
|
for (uint256 i = 0; i < length; i++) {
|
|
if (_identityRegistries[i] == _identityRegistry) {
|
|
_identityRegistries[i] = _identityRegistries[length - 1];
|
|
_identityRegistries.pop();
|
|
break;
|
|
}
|
|
}
|
|
removeAgent(_identityRegistry);
|
|
emit IdentityRegistryUnbound(_identityRegistry);
|
|
}
|
|
|
|
/**
|
|
* @dev See {IIdentityRegistryStorage-linkedIdentityRegistries}.
|
|
*/
|
|
function linkedIdentityRegistries() external view override returns (address[] memory) {
|
|
return _identityRegistries;
|
|
}
|
|
|
|
/**
|
|
* @dev See {IIdentityRegistryStorage-storedIdentity}.
|
|
*/
|
|
function storedIdentity(address _userAddress) external view override returns (IIdentity) {
|
|
return _identities[_userAddress].identityContract;
|
|
}
|
|
|
|
/**
|
|
* @dev See {IIdentityRegistryStorage-storedInvestorCountry}.
|
|
*/
|
|
function storedInvestorCountry(address _userAddress) external view override returns (uint16) {
|
|
return _identities[_userAddress].investorCountry;
|
|
}
|
|
}
|